home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS069.dsk / KINGDOM.bas < prev    next >
BASIC Source File  |  2012-02-16  |  10KB  |  295 lines
  1. 10  GOSUB 2100
  2. 14  HOME 
  3. 15  VTAB 12: INPUT "DO YOU WISH OFFICIAL RULES AND INFO Y/N";A$
  4. 16  IF A$ = "Y"  THEN 2300
  5. 17  GOTO 20
  6. 20  HOME 
  7. 25  DEF  FN R(Z1) =  INT( INT(Z1) * RND(8))
  8. 30  DEF  FN L(Z2) =  FN R(100) -Z2
  9. 100 Y = 0
  10. 105 L0 = 10 ^6
  11. 110 L1 = 3
  12. 115 N0 =  FN R(75) +75
  13. 120 L2 =  FN R(250) +250
  14. 125 N1 =  FN R(3000) +2000
  15. 130 L3 = 0
  16. 135 N2 = 0
  17. 136  PRINT 
  18. 139  SPEED= 180
  19. 140  PRINT "<*> <*> <*> <*> <*> <*> <*> <*> <*> <*>"
  20. 145  PRINT 
  21. 150  PRINT  TAB( 12)"REPORT FOR YEAR ";Y
  22. 155  PRINT 
  23. 160  PRINT "POPULATION IS ";N0
  24. 162  PRINT 
  25. 165  PRINT "ACRES OF LAND OWNED ";L2
  26. 170  PRINT "BUSHELS IN STORAGE ";N1
  27. 175  PRINT "PRICE OF LAND IS ";L1;" BUSHELS PER ACRE"
  28. 180  PRINT 
  29. 215  PRINT  TAB( 7): INPUT "HOW MANY ACRES TO BUY ?";B
  30. 220  IF B >0  THEN 295
  31. 225 B =  INT(B)
  32. 230  IF B <0 GOTO 2020
  33. 235  IF B = 0 GOTO 270
  34. 240 A = N1 -B *L1
  35. 245  IF A > = 0 GOTO 260
  36. 250  PRINT "YOUR STORAGE IS 0NLY ";N1;" BUSHELS !"
  37. 255  GOTO 215
  38. 260 N1 = A
  39. 265 L2 = L2 +B
  40. 270  PRINT  TAB( 7): INPUT "TO SELL ?";C
  41. 280 C =  INT(C)
  42. 285  IF C <0 GOTO 2020
  43. 290  IF C = 0 GOTO 325
  44. 295 A = L2 -C
  45. 300  IF A > = 0 GOTO 315
  46. 305  PRINT "YOU ONLY OWN ";L2;" ACRES !"
  47. 310  GOTO 270
  48. 315 L2 = A
  49. 320 N1 = N1 +C *L1
  50. 325  IF (B +C) = 0 GOTO 335
  51. 330  PRINT "TRANSACTION RESULTS: LAND= ";L2" ACRES.
  52. 332  PRINT  TAB( 10)"GRAIN= ";N1;" BUSHELS.
  53. 335  IF (L2 +N1 -L0) > = 0 GOTO 2010
  54. 340  IF N1 = 0 GOTO 490
  55. 350  PRINT  TAB( 6): INPUT "HOW MANY BUSHELS FOR FOOD ?";N2
  56. 360 N2 =  INT(N2)
  57. 365  IF N2 <0 GOTO 2020
  58. 370 A = N1 -N2
  59. 375  IF A > = 0 GOTO 390
  60. 380  PRINT "YOUR STORAGE IS ONLY ";N1;" BUSHELS !"
  61. 385  GOTO 350
  62. 390 N1 = A
  63. 395  IF N1 = 0 GOTO 490
  64. 400  PRINT  TAB( 5): INPUT "HOW MANY ACRES TO BE PLANTED ?";L3
  65. 410 L3 =  INT(L3)
  66. 415  IF L3 <0 GOTO 2020
  67. 420  IF L3 = 0 GOTO 500
  68. 425  IF (L2 -L3) > = 0 GOTO 440
  69. 430  PRINT "YOU ONLY OWN ";L2;" ACRES !"
  70. 435  GOTO 400
  71. 440  IF (2 *N0 -L3) > = 0 GOTO 455
  72. 445  PRINT "YOUR POPULATION IS ONLY ";N0;" PEOPLE !"
  73. 450  GOTO 400
  74. 455 A = N1 -3 *L3
  75. 460  IF A > = 0 GOTO 475
  76. 465  PRINT "YOUR STORAGE IS ONLY ";N1;" BUSHELS !"
  77. 470  GOTO 400
  78. 475 N1 = A
  79. 480  IF N1 >0 GOTO 500
  80. 485  PRINT 
  81. 490  INVERSE : PRINT "YOUR STORAGE IS NOW EMPTY...GOOD LUCK<CTRL-G><CTRL-G><CTRL-G> !": NORMAL 
  82. 500 Y = Y +1
  83. 505 N3 =  FN R(N0/3 +3)
  84. 510 N4 =  FN R(N0/4 +2)
  85. 515 N5 = N0 - INT(N2/10)
  86. 520  IF N5 >0 GOTO 560
  87. 525  IF N5 = 0 GOTO 590
  88. 535 A =  FN R(3 -N5/2)
  89. 536  PRINT 
  90. 540  PRINT  TAB( 9): INVERSE : PRINT ">>> FOOD SURPLUS <<<": NORMAL 
  91. 542  PRINT  TAB( 6)"POPULATION INCREASE= "A;" PEOPLE"
  92. 545 N5 = 0
  93. 550 N3 = N3 +A
  94. 555  GOTO 590
  95. 560  IF ( FN L(5 *(N5 -2))) >0 GOTO 590
  96. 565 A =  FN R((N5 *N1)/(2 *N0))
  97. 570  PRINT 
  98. 575  INVERSE : PRINT ">>> FOOD RIOTS <<<";: NORMAL : PRINT  TAB( 22)A;" BUSHELS LOST !"
  99. 580 N1 = N1 -A
  100. 590  IF  FN L(10) >0 GOTO 620
  101. 595 A =  INT(N0/3) + FN R(N0/2 +2)
  102. 600  PRINT 
  103. 605  INVERSE : PRINT ">>>>>>>>>>>>> P L A G U E <<<<<<<<<<<<<": NORMAL 
  104. 606  PRINT  TAB( 17)A;" DIED !"
  105. 610 N4 = N4 +A
  106. 620  IF  FN L(10) >0 GOTO 670
  107. 625 A =  FN R(N0/5) + INT(N0/5)
  108. 630 B =  FN R(N1/20) + INT(N1/20)
  109. 635 C =  FN R(L2/50)
  110. 640  PRINT 
  111. 645  FLASH : PRINT ">>>>>>>>>>> THE HUNS ATTACK <<<<<<<<<<<": NORMAL 
  112. 650  PRINT  TAB( 12)A;" PEOPLE KILLED !"
  113. 652  PRINT  TAB( 12)B;" BUSHELS TAKEN !"
  114. 653  PRINT  TAB( 12)C;" ACRES DESTROYED !"
  115. 655 N4 = N4 +A
  116. 660 N1 = N1 -B
  117. 665 L2 = L2 -C
  118. 670  IF  FN L(15) >0 GOTO 705
  119. 675 A =  FN R(20) +10
  120. 680 B =  FN R(N0 +250) +50
  121. 685  PRINT 
  122. 690  PRINT  TAB( 8): INVERSE : PRINT ">>> BORDER EXPANSION <<<": NORMAL 
  123. 693  PRINT  TAB( 10)"YOU GAINED ";A;" PEOPLE !"
  124. 694  PRINT  TAB( 16)B;" ACRES !"
  125. 695 N3 = N3 +A
  126. 700 L2 = L2 +B
  127. 705 N0 = N0 +N3 -N4 -N5
  128. 710  IF N0 < = 0 GOTO 2015
  129. 715  PRINT 
  130. 720  PRINT  TAB( 12)N3;" ARRIVED"
  131. 725  PRINT  TAB( 12)N5;" DIED OF STARVATION"
  132. 730  PRINT  TAB( 12)N4;" DIED OF NATURAL CAUSES"
  133. 735  IF  FN L(10) >0 GOTO 760
  134. 740 A =  FN R(N1/20) + INT(N1/20)
  135. 745  PRINT 
  136. 750  PRINT  TAB( 13): INVERSE : PRINT ">>> THEFT <<<": NORMAL 
  137. 752  PRINT  TAB( 11)A;" BUSHELS STOLEN !"
  138. 755 N1 = N1 -A
  139. 760  IF  FN L(10) >0 GOTO 785
  140. 765 A =  FN R(L2/10) + INT(L2/20)
  141. 770  PRINT 
  142. 775  INVERSE : PRINT ">>>>>>>>>>>>> EARTHQUAKE <<<<<<<<<<<<<<": NORMAL 
  143. 778  PRINT  TAB( 11)A;" ACRES DESTROYED !"
  144. 780 L2 = L2 -A
  145. 785  IF  FN L(15) >0 GOTO 810
  146. 790 A =  FN R(100 + INT(L2/100)) +500
  147. 795  PRINT 
  148. 800  PRINT  TAB( 6): INVERSE : PRINT ">>> GRAIN SHIPMENT ARRIVES <<<": NORMAL 
  149. 804  PRINT  TAB( 14)A;" BUSHELS !"
  150. 805 N1 = N1 +A
  151. 810  IF  FN L(15) >0 GOTO 835
  152. 815 L1 =  FN R(2) +1
  153. 820  PRINT 
  154. 825  PRINT  TAB( 12): INVERSE : PRINT ">>> DROUGHT <<<": NORMAL 
  155. 830  GOTO 860
  156. 835  IF  FN L(15) >0 GOTO 852
  157. 840 L1 =  FN R(3) +7
  158. 845  PRINT 
  159. 850  PRINT  TAB( 13): FLASH : PRINT "*** RAIN ***": NORMAL 
  160. 851  GOTO 860
  161. 852 L1 =  FN R(4) +3
  162. 860 A = L1 *L3
  163. 865 B =  FN R(A/2)
  164. 870 C = A -B
  165. 885  IF A = 0 GOTO 910
  166. 890  PRINT "   HARVEST WAS ";L1;" BUSHELS PER ACRE."
  167. 892  PRINT  TAB( 5)"FOR A TOTAL OF= ";A;" BUSHELS."
  168. 895  PRINT  TAB( 5)"LOSS TO RATS ";B;" BUSHELS."
  169. 897  PRINT  TAB( 5)"NET HARVEST WAS= ";C;" BUSHELS."
  170. 900 N1 = N1 +C
  171. 905  GOTO 130
  172. 910  PRINT  TAB( 5)"HARVEST WAS ";L1;" BUSHELS PER ACRE"
  173. 912  PRINT  TAB( 5)"FOR A TOTAL OF ";A;" BUSHELS."
  174. 915  GOTO 900
  175. 2010  PRINT : PRINT : PRINT 
  176. 2011  PRINT "*********** CONGRADULATIONS ***********"
  177. 2013  PRINT ">>>>>>>> YOU NOW RULE THE WORLD <<<<<<<"
  178. 2014  GOTO 2020
  179. 2015  PRINT 
  180. 2016  FLASH : PRINT ">>>>>>>>>>><CTRL-G> D<CTRL-G> I<CTRL-G> S<CTRL-G> T<CTRL-G> A<CTRL-G> S<CTRL-G> T<CTRL-G> E<CTRL-G> R<CTRL-G> <<<<<<<<<<": NORMAL 
  181. 2017  PRINT : PRINT "    THERE ARE NO MORE PEOPLE LEFT<CTRL-G> !"
  182. 2020  PRINT : PRINT 
  183. 2021  PRINT "<*> YOUR REIGN LASTED FOR ";Y;" YEARS <*>"
  184. 2022  PRINT : PRINT : PRINT "<*> <*> <*> <*> <*> <*> <*> <*> <*> <*>"
  185. 2046  END 
  186. 2100  HOME : FOR I = 1073 TO 1093: POKE I,32: POKE I +768,32: NEXT I
  187. 2110  FOR I = 1202 TO 1843  STEP 128: POKE I,32: POKE I +18,32: NEXT I
  188. 2120  POKE 1335,65: POKE 1337,80: POKE 1339,80: POKE 1341,76: POKE 1343,69
  189. 2130  POKE 1589,139: POKE 1591,137: POKE 1593,142: POKE 1595,135: POKE 1597,132: POKE 1599,143: POKE 1601,141
  190. 2140  FOR I = 2012 TO 2026: POKE I,32: NEXT I
  191. 2150  FOR I = 1885 TO 1897: POKE I,32: NEXT I
  192. 2160  FOR I = 1974 TO 1758  STEP 128: POKE I,32: POKE I +2,32: NEXT I
  193. 2170  FOR I = 1118 TO 1758  STEP 128: POKE I,32: POKE I +2,32: NEXT I
  194. 2180  FOR I = 1126 TO 1766  STEP 128: POKE I,32: POKE I +2,32: NEXT I
  195. 2190  POKE 1982,32: POKE 1984,32
  196. 2200  FOR I = 1119 TO 1756  STEP 128: POKE I,170: POKE I +8,170: NEXT I
  197. 2210  FOR I = 1936 TO 1942: POKE I,58: NEXT I
  198. 2220  FOR I = 1808 TO 1814: POKE I,158: NEXT I
  199. 2230  POKE 1683,129
  200. 2240  POKE 1555,107
  201. 2250  FOR N = 1 TO 4000: NEXT N: RETURN 
  202. 2300  HOME : PRINT  TAB( 10)"OFFICIAL RULES FOR"
  203. 2310  VTAB 3: PRINT  TAB( 9)"<*> K I N G D O M <*>"
  204. 2315  PRINT 
  205. 2320  PRINT " THE GAME OF APPLE KINGDOM IS BASED UPON"
  206. 2325  PRINT 
  207. 2340  PRINT " THE PREMISE THAT THE PLAYER IS TO ACT"
  208. 2350  PRINT " AS THE RULER OF A MYTHICAL,MEDIEVAL"
  209. 2360  PRINT " COUNTRY. THE RULER MUST MAKE DECISIONS"
  210. 2370  PRINT " WHICH MAINTAIN THE KINGDOM AND ADVANCE"
  211. 2380  PRINT " THE PLAYER TOWARD THE GOAL."
  212. 2390  PRINT " THE GOAL OF THE PLAYER IS TO RULE THE"
  213. 2400  PRINT " WORLD !. THIS IS ACCOMPLISHED BY"
  214. 2410  PRINT " COLLECTING A TOTAL WEALTH EQUAL TO, OR"
  215. 2420  PRINT " EXCEEDING ONE MILLION UNITS. WEALTH IS"
  216. 2430  PRINT " MEASURED IN TERMS OF TWO QUANITIES:"
  217. 2440  PRINT " ACRES OF LAND OWNED, AND BUSHELS OF"
  218. 2450  PRINT " GRAIN IN STORAGE."
  219. 2455  VTAB 23
  220. 2460  PRINT " TO CONTINUE HIT ANY KEY !": GET K$: GOTO 2470
  221. 2465  END 
  222. 2470  HOME : PRINT  TAB( 8)"<*> GAME CONSTANTS <*>"
  223. 2485  PRINT 
  224. 2490  PRINT "*FOOD-EACH SUBJECT REQUIRES A MINIMUM"
  225. 2500  PRINT "OF 10 BUSHELS OF GRAIN PER YEAR AS FOOD"
  226. 2505  PRINT 
  227. 2510  PRINT "*SEED-EACH ACRE PLANTED REQUIRES 3"
  228. 2520  PRINT "BUSHELS OF GRAIN PER YEAR FOR SEED."
  229. 2525  PRINT 
  230. 2530  PRINT "*LABOR-EACH SUBJECT MAY PLANT A MAXIMUM"
  231. 2540  PRINT "OF 2 ACRES PER YEAR."
  232. 2545  PRINT 
  233. 2550  PRINT "*LAND PRICE-VARIES BETWEEN 3 AND 6"
  234. 2560  PRINT "BUSHELS PER ACRE. 
  235. 2565  PRINT 
  236. 2570  PRINT "*POPULATION-VARIES BETWEEN 20 TO 40 %"
  237. 2575  PRINT 
  238. 2580  PRINT "*GRAIN LOSS-VARIES BETWEEN 0 AND 50 %"
  239. 2582  VTAB 23: PRINT " TO CONTINUE HIT ANY KEY !": GET K$: GOTO 2588
  240. 2584  END 
  241. 2588  HOME : VTAB 4
  242. 2590  PRINT "*OVERFEEDING-A FOOD SURPLUS OCCURS WHEN"
  243. 2600  PRINT "MORE GRAIN IS ALLOTED FOR FOOD THEN THE"
  244. 2610  PRINT "MINIMAL REQUIREMENT. THERE IS ABOUT"
  245. 2620  PRINT "A 50% CHANCE OF GAINING 1 PERSON FOR"
  246. 2630  PRINT "EACH 20 BUSHELS OVER THE MINIMUM."
  247. 2635  PRINT : PRINT 
  248. 2640  PRINT "*UNDERFEEDING-THE RULER MAY STARVE OFF"
  249. 2650  PRINT "2 PERSONS PER YEAR WITHOUT ILL EFFECT."
  250. 2660  PRINT "EACH STARVATION OVER 2 INCREASES THE"
  251. 2670  PRINT "CHANCES OF FOOD RIOTS BY 5% EACH."
  252. 2680  PRINT "A FOOD RIOT MAT RESULT IN A LOSS OF UP"
  253. 2690  PRINT "50% OF THE GRAIN IN STORAGE !"
  254. 2695  VTAB 23: PRINT " TO CONTINUE HIT ANY KEY !": GET K$: GOTO 2699
  255. 2696  END 
  256. 2699  HOME : PRINT  TAB( 9)"<*> RANDOM FACTORS <*>"
  257. 2700  PRINT : PRINT "*PLAGUE-(10%)-MAY REDUCE POPULATION"
  258. 2710  PRINT "UP TO 80% !"
  259. 2715  PRINT 
  260. 2720  PRINT "*THEFT-(10%)-MAY REDUCE GRAIN STORAGE"
  261. 2730  PRINT "UP TO 10% !"
  262. 2735  PRINT 
  263. 2740  PRINT "*EARTHQUAKE-(10%)-MAY REDUCE ACREAGE"
  264. 2750  PRINT "UP TO 15% !"
  265. 2754  PRINT 
  266. 2770  PRINT : PRINT "*ATTACK BY HUNS-(10%)-MAY REDUCE"
  267. 2780  PRINT "POPULATION UP TO 40%, STORAGE UP TO 10%"
  268. 2790  PRINT "AND LAND UP TO 2% !"
  269. 2795  PRINT 
  270. 2800  PRINT "*RAIN-(15%)-INCREASES HARVEST TO 7, 8"
  271. 2810  PRINT "OR 9 BUSHELS PER ACRE !"
  272. 2815  PRINT 
  273. 2820  PRINT "*DROUGHT-(15%)-DECREASES HARVEST TO 1"
  274. 2830  PRINT "OR 2 BUSHELS PER ACRE !"
  275. 2835  VTAB 23: PRINT "TO CONTINUE HIT ANY KEY !": GET K$: GOTO 2840
  276. 2836  END 
  277. 2840  HOME : VTAB 8: PRINT "*GRAIN SHIPMENT-(15%)-INCREASES GRAIN"
  278. 2850  PRINT "STORAGE, DEPENDS ON THE SIZE OF THE"
  279. 2860  PRINT "KINGDOM ( ACRES OF LAND ) !"
  280. 2865  PRINT : PRINT 
  281. 2870  PRINT "*BORDER EXPANSION-(15%)-INCREASES"
  282. 2880  PRINT "POPULATION AND LAND, DEPENDS ON PRESENT"
  283. 2890  PRINT "POPULATION OF KINGDOM !"
  284. 2900  VTAB 22: PRINT "IF YOU ARE READY TO RULE APPLE KINGDOM,"
  285. 2910  PRINT : PRINT "TYPE A 'Y' AND GIVE IT A GO,GOOD LUCK !"
  286. 2920  INPUT A$
  287. 2930  IF A$ = "Y"  THEN 20
  288. 2940  END 
  289. 65535  REM :TITLE DESIGN BY ALEX AND CHRIS MASSIMO.
  290. 65535  REM :THIS PROGRAM WAS ADAPTED FOR THE APPLE"
  291. 65535  REM :BY ALEX AND CHRIS MASSIMO.
  292. 65535  REM :DONATED TO THE APPLECORPS OF SAN DIEGO.
  293. 65535  REM  :IF YOU WISH TO CHANGE THE SPEED, REDO LINE # 139.
  294. 65535  REM :IF YOU WISH DIFFERENT RANDOM FIGURES.
  295. 65535  REM :YOU MAY WISH TO CHANGE LINE # 25.